excel函數問題

欄位E2:5、欄位F2:7、欄位G2:9,加總少於39,就倒扣39

欄位E2:15、欄位F2:17、欄位G2:19,加總51,超過39,就倒扣78

函數要如何設定

我這裡有倒扣39的函數=IF((E2+F2+G2)>39,( E2+F2+G2-39),( E2+F2+G2))

,如何再設定,如果沒超過39就倒扣39,如超過39就倒扣78的函數要如何改?

7 個解答

評分
  • Daniel
    Lv 7
    7 年前
    最佳解答

    若加總等於39時不倒扣,則:

    =SUM(E2:G2)-TEXT(SUM(E2:G2)-39,"78;39;0")

    若加總等於39時倒扣39,則:

    =SUM(E2:G2)-TEXT(SUM(E2:G2)-39,"78;39;39")

    =SUM(E2:G2)-TEXT(SUM(E2:G2)-39,"2;1;1")*39

    若加總等於39時倒扣78,則:

    =SUM(E2:G2)-TEXT(SUM(E2:G2)-39,"78;39")

    2014-04-21 13:25:03 補充:

    =E2+F2+G2-SUM((E2+F2+G2>{39,78})*1)*39

    =E2+F2+G2+INT(1-(E2+F2+G2)/39)*39

    2014-04-21 13:44:22 補充:

    亦可試試:

    =MOD(E2+F2+G2-1,39)+1

    =MOD(E2+F2+G2,39)

    二式在等於39的倍數時會有差異

    2014-04-21 14:05:45 補充:

    請問上述哪些式子符合版大實際需求,好轉到回答區

    2014-04-21 14:37:35 補充:

    以版大的補充問題修正,超過39扣39,超過78扣78,可用下列公式:=E2+F2+G2-SUM((E2+F2+G2>{39,78})*1)*39 或

    =E2+F2+G2+INT(1-(E2+F2+G2)/39)*39 或

    =MOD(E2+F2+G2-1,39)+1

    第2,3式在超過39的3倍時會與第1式答案不同,若不會超過的話,則三式皆可用。

  • 匿名使用者
    7 年前

    下面的網址應該對你有幫助

    http://phi008780426.pixnet.net/blog

  • 匿名使用者
    7 年前

    下面的網址應該對你有幫助

    http://phi008780424.pixnet.net/blog

  • 匿名使用者
    7 年前

    發問者你好:

    幫你整理好了,詳細資料在這邊

    http://adf.ly/k1RTS

    希望其他回答者也認同我意見^^

  • 您覺得這個回答如何?您可以登入為回答投票。
  • 7 年前

    不好意思,再補充一下,是超過39扣39,超過78扣78,這樣要如何修正呢?感謝。

    2014-04-21 13:52:42 補充:

    Daniel 大師~~謝謝您了~到時再贈送點數給您~感恩^^

    2014-04-21 14:22:22 補充:

    這個符合需求~感恩囉^^

    =E2+F2+G2-SUM((E2+F2+G2>{39,78})*1)*39

    =E2+F2+G2+INT(1-(E2+F2+G2)/39)*39

  • 7 年前

    =IF((E2+F2+G2)>39,(E2+F2+G2-78),(E2+F2+G2-39))

    2014-04-21 10:24:42 補充:

    原本解答的寫法,=IF((E2+F2+G2)>39,(E2+F2+G2-78),(E2+F2+G2-39))

    如果總和=39的時候,則倒扣39

    如果樓主想要總和=39的時候,則到扣78

    那函數要改成

    =IF((E2+F2+G2)>=39,(E2+F2+G2-78),(E2+F2+G2-39))

    參考資料: 自己, 自己補充
  • 7 年前

    試試如下:

    =IF(E2+F2+G2>39,E2+F2+G2-78,IF(E2+F2+G2<39,E2+F2+G2-39,E2+F2+G2))

還有問題?馬上發問,尋求解答。